;redcode-qs
;name FragMini-Q^2 AQP
;author John Metcalf
;strategy Fragility's Mini-Q^2 with A Quickscanner's Paper
;strategy 26 scans with a 44 line qscan
;strategy this is the first qscan I ever wrote :-)
;assert CORESIZE == 8000

     qf equ (qGo+1111)
     qd equ (227)
     qs equ (qd*2)
     qi equ (7)

qGo: seq   qf,       qd+qf
     jmp   qFas,     }qf+2

     seq   qf+qs*2,  qd+qf+qs*2
     jmp   qSet,     <qPnt
     seq   qf+qs*3,  qd+qf+qs*3
     jmp   qSet,     >qPnt
     seq   qf+qs,    qd+qf+qs
     jmp   qSet,     {qf+qs+2

     seq   qf+qs*10, qd+qf+qs*10
     jmp   >qSet,    {qPnt
     seq   qf+qs*4,  qd+qf+qs*4
     jmp   >qSet,    }qPnt
     seq   qf+qs*6,  qd+qf+qs*6
     jmp   >qSet,    {qf+qs*6+2

     seq   qf+qs*8,  qd+qf+qs*8
     jmp   @qSet,    <qPnt
     seq   qf+qs*9,  qd+qf+qs*9
     jmp   @qSet,    >qPnt
     seq   qf+qs*12, qd+qf+qs*12
     djn.f @qSet,    qPnt

     seq   qf+qs*11, qd+qf+qs*11
     jmp   @qSet,    {qPnt
     seq   qf+qs*5,  qd+qf+qs*5
     jmp   @qSet,    }qPnt
     sne   qf+qs*7,  qd+qf+qs*7
     jmp   pGo,      {2493

     add.f *qPnt,    qKil
qSet:add.f @qPnt,    @-1

qFas:sne   qGo-1,    @qKil
     add   qDis,     qKil

qLoo:mov   qPnt,     *qKil
qKil:mov   qf+4,     qf
     add   qInc,     qKil
     djn   qLoo,     #10

     jmp   pGo,      {2584

qDis:dat   qd,       qd
qInc:dat   -qi,      qi
qPnt:dat   >qTb1,    >qTb2

     dat   10*qs,    10*qs
qTb1:dat   6*qs,     6*qs
     dat   4*qs,     4*qs

     dat   2*qs,     2*qs
qTb2:dat   qs,       qs
     dat   3*qs,     3*qs

     for   43
     dat   0,        0
     rof

        pGo     EQU     boot

	pStep1	EQU	2341
	pStep2	EQU	2421
	pStep3	EQU	3241

	pAway1	EQU	2000
	pAway2	EQU	6000

	pEnd	EQU	(silk3 + 1)

boot	spl	1
	mov.i	-1,		0
	spl	1

	mov.i	< pBoot1,	{ pBoot1
pBoot1	spl	pAway1,		pEnd

	mov.i	< pBoot2,	{ pBoot2
pBoot2	jmp	pAway2,		pEnd

silk1	spl	@ silk1,	< pStep1
	mov.i	} silk1,	> silk1

silk2	spl	@ silk2,	< pStep2
	mov.i	} silk2,	> silk2

	mov.i	{ silk2,	< silk3
silk3	djn.f	@ silk3,	< pStep3

	END